[eb3ca82] | 1 | include(qpdfview.pri) |
---|
| 2 | |
---|
| 3 | TARGET = qpdfview |
---|
| 4 | TEMPLATE = app |
---|
| 5 | |
---|
| 6 | OBJECTS_DIR = objects |
---|
| 7 | MOC_DIR = moc |
---|
| 8 | |
---|
| 9 | HEADERS += \ |
---|
| 10 | sources/global.h \ |
---|
| 11 | sources/renderparam.h \ |
---|
| 12 | sources/printoptions.h \ |
---|
| 13 | sources/settings.h \ |
---|
| 14 | sources/model.h \ |
---|
| 15 | sources/pluginhandler.h \ |
---|
| 16 | sources/shortcuthandler.h \ |
---|
| 17 | sources/rendertask.h \ |
---|
| 18 | sources/tileitem.h \ |
---|
| 19 | sources/pageitem.h \ |
---|
| 20 | sources/thumbnailitem.h \ |
---|
| 21 | sources/presentationview.h \ |
---|
| 22 | sources/searchmodel.h \ |
---|
| 23 | sources/searchitemdelegate.h \ |
---|
| 24 | sources/searchtask.h \ |
---|
| 25 | sources/miscellaneous.h \ |
---|
| 26 | sources/documentlayout.h \ |
---|
| 27 | sources/documentview.h \ |
---|
| 28 | sources/printdialog.h \ |
---|
| 29 | sources/settingsdialog.h \ |
---|
| 30 | sources/fontsdialog.h \ |
---|
| 31 | sources/helpdialog.h \ |
---|
| 32 | sources/recentlyusedmenu.h \ |
---|
| 33 | sources/recentlyclosedmenu.h \ |
---|
| 34 | sources/bookmarkmodel.h \ |
---|
| 35 | sources/bookmarkmenu.h \ |
---|
| 36 | sources/bookmarkdialog.h \ |
---|
| 37 | sources/database.h \ |
---|
| 38 | sources/mainwindow.h |
---|
| 39 | |
---|
| 40 | SOURCES += \ |
---|
| 41 | sources/settings.cpp \ |
---|
| 42 | sources/pluginhandler.cpp \ |
---|
| 43 | sources/shortcuthandler.cpp \ |
---|
| 44 | sources/rendertask.cpp \ |
---|
| 45 | sources/tileitem.cpp \ |
---|
| 46 | sources/pageitem.cpp \ |
---|
| 47 | sources/thumbnailitem.cpp \ |
---|
| 48 | sources/presentationview.cpp \ |
---|
| 49 | sources/searchmodel.cpp \ |
---|
| 50 | sources/searchitemdelegate.cpp \ |
---|
| 51 | sources/searchtask.cpp \ |
---|
| 52 | sources/miscellaneous.cpp \ |
---|
| 53 | sources/documentlayout.cpp \ |
---|
| 54 | sources/documentview.cpp \ |
---|
| 55 | sources/printdialog.cpp \ |
---|
| 56 | sources/settingsdialog.cpp \ |
---|
| 57 | sources/fontsdialog.cpp \ |
---|
| 58 | sources/helpdialog.cpp \ |
---|
| 59 | sources/recentlyusedmenu.cpp \ |
---|
| 60 | sources/recentlyclosedmenu.cpp \ |
---|
| 61 | sources/bookmarkmenu.cpp \ |
---|
| 62 | sources/bookmarkdialog.cpp \ |
---|
| 63 | sources/bookmarkmodel.cpp \ |
---|
| 64 | sources/database.cpp \ |
---|
| 65 | sources/mainwindow.cpp \ |
---|
| 66 | sources/main.cpp |
---|
| 67 | |
---|
| 68 | DEFINES += APPLICATION_VERSION=\\\"$${APPLICATION_VERSION}\\\" |
---|
| 69 | |
---|
| 70 | QT += core gui |
---|
| 71 | |
---|
| 72 | greaterThan(QT_MAJOR_VERSION, 4): QT += concurrent widgets printsupport |
---|
| 73 | |
---|
| 74 | !without_svg { |
---|
| 75 | DEFINES += WITH_SVG |
---|
| 76 | QT += svg |
---|
| 77 | |
---|
| 78 | RESOURCES += icons.qrc |
---|
| 79 | } |
---|
| 80 | |
---|
| 81 | !without_sql { |
---|
| 82 | DEFINES += WITH_SQL |
---|
| 83 | QT += sql |
---|
| 84 | } |
---|
| 85 | |
---|
| 86 | !without_dbus { |
---|
| 87 | DEFINES += WITH_DBUS |
---|
| 88 | QT += dbus |
---|
| 89 | } |
---|
| 90 | |
---|
| 91 | DEFINES += PLUGIN_INSTALL_PATH=\\\"$${PLUGIN_INSTALL_PATH}\\\" |
---|
| 92 | |
---|
| 93 | !without_pdf { |
---|
| 94 | DEFINES += WITH_PDF |
---|
| 95 | |
---|
| 96 | !without_pkgconfig:POPPLER_VERSION = $$system(pkg-config --modversion poppler-qt$${QT_MAJOR_VERSION}) |
---|
| 97 | DEFINES += POPPLER_VERSION=\\\"$${POPPLER_VERSION}\\\" |
---|
| 98 | |
---|
| 99 | static_pdf_plugin { |
---|
| 100 | isEmpty(PDF_PLUGIN_NAME):PDF_PLUGIN_NAME = libqpdfview_pdf.a |
---|
| 101 | |
---|
| 102 | DEFINES += STATIC_PDF_PLUGIN |
---|
| 103 | LIBS += $$PDF_PLUGIN_NAME |
---|
| 104 | PRE_TARGETDEPS += $$PDF_PLUGIN_NAME |
---|
| 105 | |
---|
| 106 | QT += xml |
---|
| 107 | |
---|
| 108 | !without_pkgconfig { |
---|
| 109 | CONFIG += link_pkgconfig |
---|
| 110 | PKGCONFIG += poppler-qt$${QT_MAJOR_VERSION} |
---|
| 111 | } |
---|
| 112 | } else { |
---|
| 113 | isEmpty(PDF_PLUGIN_NAME):PDF_PLUGIN_NAME = libqpdfview_pdf.so |
---|
| 114 | } |
---|
| 115 | |
---|
| 116 | DEFINES += PDF_PLUGIN_NAME=\\\"$${PDF_PLUGIN_NAME}\\\" |
---|
| 117 | } |
---|
| 118 | |
---|
| 119 | !without_ps { |
---|
| 120 | DEFINES += WITH_PS |
---|
| 121 | |
---|
| 122 | !without_pkgconfig:LIBSPECTRE_VERSION = $$system(pkg-config --modversion libspectre) |
---|
| 123 | DEFINES += LIBSPECTRE_VERSION=\\\"$${LIBSPECTRE_VERSION}\\\" |
---|
| 124 | |
---|
| 125 | static_ps_plugin { |
---|
| 126 | isEmpty(PS_PLUGIN_NAME):PS_PLUGIN_NAME = libqpdfview_ps.a |
---|
| 127 | |
---|
| 128 | DEFINES += STATIC_PS_PLUGIN |
---|
| 129 | LIBS += $$PS_PLUGIN_NAME |
---|
| 130 | PRE_TARGETDEPS += $$PS_PLUGIN_NAME |
---|
| 131 | |
---|
| 132 | !without_pkgconfig { |
---|
| 133 | CONFIG += link_pkgconfig |
---|
| 134 | PKGCONFIG += libspectre |
---|
| 135 | } |
---|
| 136 | } else { |
---|
| 137 | isEmpty(PS_PLUGIN_NAME):PS_PLUGIN_NAME = libqpdfview_ps.so |
---|
| 138 | } |
---|
| 139 | |
---|
| 140 | DEFINES += PS_PLUGIN_NAME=\\\"$${PS_PLUGIN_NAME}\\\" |
---|
| 141 | } |
---|
| 142 | |
---|
| 143 | !without_djvu { |
---|
| 144 | DEFINES += WITH_DJVU |
---|
| 145 | |
---|
| 146 | !without_pkgconfig:DJVULIBRE_VERSION = $$system(pkg-config --modversion ddjvuapi) |
---|
| 147 | DEFINES += DJVULIBRE_VERSION=\\\"$${DJVULIBRE_VERSION}\\\" |
---|
| 148 | |
---|
| 149 | static_djvu_plugin { |
---|
| 150 | isEmpty(DJVU_PLUGIN_NAME):DJVU_PLUGIN_NAME = libqpdfview_djvu.a |
---|
| 151 | |
---|
| 152 | DEFINES += STATIC_DJVU_PLUGIN |
---|
| 153 | LIBS += $$DJVU_PLUGIN_NAME |
---|
| 154 | PRE_TARGETDEPS += $$DJVU_PLUGIN_NAME |
---|
| 155 | |
---|
| 156 | !without_pkgconfig { |
---|
| 157 | CONFIG += link_pkgconfig |
---|
| 158 | PKGCONFIG += ddjvuapi |
---|
| 159 | } |
---|
| 160 | } else { |
---|
| 161 | isEmpty(DJVU_PLUGIN_NAME):DJVU_PLUGIN_NAME = libqpdfview_djvu.so |
---|
| 162 | } |
---|
| 163 | |
---|
| 164 | DEFINES += DJVU_PLUGIN_NAME=\\\"$${DJVU_PLUGIN_NAME}\\\" |
---|
| 165 | } |
---|
| 166 | |
---|
| 167 | with_fitz { |
---|
| 168 | DEFINES += WITH_FITZ |
---|
| 169 | |
---|
| 170 | DEFINES += FITZ_VERSION=\\\"$${FITZ_VERSION}\\\" |
---|
| 171 | |
---|
| 172 | static_fitz_plugin { |
---|
| 173 | isEmpty(FITZ_PLUGIN_NAME):FITZ_PLUGIN_NAME = libqpdfview_fitz.a |
---|
| 174 | |
---|
| 175 | DEFINES += STATIC_FITZ_PLUGIN |
---|
| 176 | LIBS += $$FITZ_PLUGIN_NAME |
---|
| 177 | PRE_TARGETDEPS += $$FITZ_PLUGIN_NAME |
---|
| 178 | |
---|
| 179 | isEmpty(FITZ_PLUGIN_LIBS) { |
---|
| 180 | LIBS += -lmupdf -lfreetype -ljbig2dec -lopenjp2 -ljpeg -lz -lm |
---|
| 181 | } else { |
---|
| 182 | LIBS += $$FITZ_PLUGIN_LIBS |
---|
| 183 | } |
---|
| 184 | } else { |
---|
| 185 | isEmpty(FITZ_PLUGIN_NAME):FITZ_PLUGIN_NAME = libqpdfview_fitz.so |
---|
| 186 | } |
---|
| 187 | |
---|
| 188 | DEFINES += FITZ_PLUGIN_NAME=\\\"$${FITZ_PLUGIN_NAME}\\\" |
---|
| 189 | } |
---|
| 190 | |
---|
| 191 | !without_image { |
---|
| 192 | DEFINES += WITH_IMAGE |
---|
| 193 | |
---|
| 194 | static_image_plugin { |
---|
| 195 | isEmpty(IMAGE_PLUGIN_NAME):IMAGE_PLUGIN_NAME = libqpdfview_image.a |
---|
| 196 | |
---|
| 197 | DEFINES += STATIC_IMAGE_PLUGIN |
---|
| 198 | LIBS += $$IMAGE_PLUGIN_NAME |
---|
| 199 | PRE_TARGETDEPS += $$IMAGE_PLUGIN_NAME |
---|
| 200 | } |
---|
| 201 | else { |
---|
| 202 | isEmpty(IMAGE_PLUGIN_NAME):IMAGE_PLUGIN_NAME = libqpdfview_image.so |
---|
| 203 | } |
---|
| 204 | |
---|
| 205 | DEFINES += IMAGE_PLUGIN_NAME=\\\"$${IMAGE_PLUGIN_NAME}\\\" |
---|
| 206 | } |
---|
| 207 | |
---|
| 208 | !without_cups { |
---|
| 209 | DEFINES += WITH_CUPS |
---|
| 210 | |
---|
| 211 | isEmpty(CUPS_VERSION):CUPS_VERSION = $$system(cups-config --version) |
---|
| 212 | isEmpty(CUPS_LIBS):CUPS_LIBS = $$system(cups-config --libs) |
---|
| 213 | |
---|
| 214 | DEFINES += CUPS_VERSION=\\\"$${CUPS_VERSION}\\\" |
---|
| 215 | LIBS += $$CUPS_LIBS |
---|
| 216 | } |
---|
| 217 | |
---|
| 218 | !without_synctex { |
---|
| 219 | DEFINES += WITH_SYNCTEX |
---|
| 220 | |
---|
| 221 | !without_pkgconfig:system(pkg-config --exists synctex) { |
---|
| 222 | CONFIG += link_pkgconfig |
---|
| 223 | PKGCONFIG += synctex |
---|
| 224 | } else { |
---|
| 225 | HEADERS += synctex/synctex_parser.h synctex/synctex_parser_utils.h synctex/synctex_parser_local.h |
---|
| 226 | SOURCES += synctex/synctex_parser.c synctex/synctex_parser_utils.c |
---|
| 227 | |
---|
| 228 | INCLUDEPATH += synctex |
---|
| 229 | LIBS += -lz |
---|
| 230 | } |
---|
| 231 | } |
---|
| 232 | |
---|
| 233 | lessThan(QT_MAJOR_VERSION, 5) : !without_magic { |
---|
| 234 | DEFINES += WITH_MAGIC |
---|
| 235 | LIBS += -lmagic |
---|
| 236 | } |
---|
| 237 | |
---|
| 238 | !without_signals { |
---|
| 239 | DEFINES += WITH_SIGNALS |
---|
| 240 | |
---|
| 241 | HEADERS += sources/signalhandler.h |
---|
| 242 | SOURCES += sources/signalhandler.cpp |
---|
| 243 | } |
---|
| 244 | |
---|
| 245 | DEFINES += DATA_INSTALL_PATH=\\\"$${DATA_INSTALL_PATH}\\\" |
---|
| 246 | |
---|
| 247 | |
---|
| 248 | DESKTOP_FILE = miscellaneous/qpdfview.desktop |
---|
| 249 | APPDATA_FILE = miscellaneous/qpdfview.appdata.xml |
---|
| 250 | |
---|
| 251 | !without_pdf|with_fitz:MIME_TYPES += application/pdf application/x-pdf text/pdf text/x-pdf image/pdf image/x-pdf |
---|
| 252 | !without_ps:MIME_TYPES += application/postscript |
---|
| 253 | !without_djvu:MIME_TYPES += image/vnd.djvu image/x-djvu |
---|
| 254 | |
---|
| 255 | system("sed -e \"s:DATA_INSTALL_PATH:$${DATA_INSTALL_PATH}:\" -e \"s:MIME_TYPES:$$join(MIME_TYPES,";","",";"):\" $${DESKTOP_FILE}.in > $${DESKTOP_FILE}") |
---|
| 256 | |
---|
| 257 | |
---|
| 258 | target.path = $${TARGET_INSTALL_PATH} |
---|
| 259 | |
---|
| 260 | data.files = translations/*.qm help/help*.html |
---|
| 261 | data.path = $${DATA_INSTALL_PATH} |
---|
| 262 | |
---|
| 263 | manual.files = miscellaneous/qpdfview.1 |
---|
| 264 | manual.path = $${MANUAL_INSTALL_PATH} |
---|
| 265 | |
---|
| 266 | icon.files = icons/qpdfview.svg |
---|
| 267 | icon.path = $${ICON_INSTALL_PATH} |
---|
| 268 | |
---|
| 269 | launcher.files = $${DESKTOP_FILE} |
---|
| 270 | launcher.path = $${LAUNCHER_INSTALL_PATH} |
---|
| 271 | |
---|
| 272 | appdata.files = $${APPDATA_FILE} |
---|
| 273 | appdata.path = $${APPDATA_INSTALL_PATH} |
---|
| 274 | |
---|
| 275 | INSTALLS += target data manual icon launcher appdata |
---|
| 276 | |
---|
| 277 | INCLUDEPATH += icons |
---|
[7eb08ea] | 278 | INCLUDEPATH += /home/pbuitrago/Cenditel/Seguridad/POA-2016/programas/poppler-0.45.0 |
---|
| 279 | INCLUDEPATH += /home/pbuitrago/Cenditel/Seguridad/POA-2016/programas/poppler-0.45.0/poppler |
---|
| 280 | #QMAKE_LIBDIR += /usr/local/lib |
---|
| 281 | |
---|
[eb3ca82] | 282 | win32:RC_FILE = icons/qpdfview_win32.rc |
---|
| 283 | os2:RC_FILE = icons/qpdfview_os2.rc |
---|